Percussion and sticking

The hand can be the note

On an unpitched percussion part, R and L are stroke notes. Durations work exactly as they do for pitched notes. A rest is still lowercase r.

scorescript 0.3
score "Single strokes" {
  parts { snare-drum }
  snare-drum {
    staff-lines 1
    m1-2 { 4R L R L | 8R L R R L R L L }
  }
}

Generated notation

Canonical spelling

scorescript 0.3
score "Single strokes" {
  parts {
    snare-drum
  }

  snare-drum {
    staff-lines 1

    m1-2 {
      4R L R L | 8R L R R L R L L
    }
  }
}

The catalog drum supplies its percussion clef. A custom part can explicitly use clef percussion. staff-lines 1 selects a one-line staff.

Flams and drags

Use the ordinary grace slash: /R L is a right grace stroke into a left main stroke; /L /L R is two left grace strokes into a right main stroke.

scorescript 0.3
score "Grace strokes" {
  parts { snare-drum }
  snare-drum { m1 { /R 4L R /L /L R L } }
}

Generated notation

Example notes (1)

• a beamed or unflagged grace note carries no slash (the slash hangs off a flag)

Canonical spelling

scorescript 0.3
score "Grace strokes" {
  parts {
    snare-drum
  }

  snare-drum {
    m1 {
      /4R L R /L /L R L
    }
  }
}

Do not use rL as a musical note: r already means rest. Lowercase hands printed by the engraver are not the source spelling of a grace note.

Hands on pitched notes

On a pitched part, keep the pitch and attach the hand as a mark after it.

4C5(R) D(L) E(R) F(L)

Generated notation

Canonical spelling

4C5(R) D(L) E(R) F(L)

Bare R on a pitched part is refused. Hand marks are technical indications, not lyric syllables.

Named rudiments

A score-level rudiment declares a hand pattern. An exercise's sticking statement applies that pattern to its attacks. The title alone does not apply hands.

scorescript 0.3
score "Paradiddle" {
  rudiment "Single paradiddle" R L R R | L R L L
  exercises {
    exercise =study {
      title "Paradiddle study"
      sticking "Single paradiddle"
      section m1
    }
  }
  parts { snare-drum }
  snare-drum { m1 { 8R L R R L R L L } }
}

Generated notation

Canonical spelling

scorescript 0.3
score "Paradiddle" {
  rudiment "Single paradiddle" R L R R | L R L L

  exercises {
    exercise =study {
      title "Paradiddle study"
      sticking "Single paradiddle"
      section m1
    }
  }

  parts {
    snare-drum
  }

  snare-drum {
    m1 {
      8R L R R L R L L
    }
  }
}

The pattern cycles through attacks. Rests and tied arrivals consume no stroke. An explicit hand wins while retaining its place in the cycle. Rudiment pattern tokens can include lR and rL for flams, and roll marks such as (trem3) or (z); the corresponding notes must actually contain the grace or roll structure. Mismatches are diagnosed. Rudiments and exercise collections remain provisional language features.